home *** CD-ROM | disk | FTP | other *** search
/ Aminet 38 / Aminet 38 (2000)(Schatztruhe)[!][Aug 2000].iso / Aminet / util / misc / BFLocalizer.lha / BFLocalizer / Examples / Bridgeboard / Suomi / PCPrefs_patch < prev    next >
Encoding:
Text File  |  2000-05-08  |  4.6 KB  |  138 lines
  1. ;-----------------------------------------------------------------------------
  2. ; TITLE        : PCPrefs_patch install
  3. ; VERSION      : 1.0
  4. ; DATE         : 06.05.2000
  5. ; AUTHOR       : Janne Peräaho
  6. ; DESCRIPTION  : Installer script for patching PCPrefs
  7. ; INPUT        : -
  8. ; OUTPUT       : -
  9. ;-----------------------------------------------------------------------------
  10. ; MODIFICATIONS: -
  11. ;-----------------------------------------------------------------------------
  12.  
  13. ; $VER: PCPrefs_patch 1.0 (6.5.2000)
  14.  
  15. ;-----------------------------------------------------------------------------
  16. ; VARIABLES VARIABLES VARIABLES VARIABLES VARIABLES VARIABLES VARIABLES VARIA
  17. ;-----------------------------------------------------------------------------
  18. ;(set #pcprefsversion "2359345") 
  19. (set #pcprefs_ver "36") ; PCPrefs version 36.49 required
  20. (set #pcprefs_rev "49") ; PCPrefs version 36.49 required
  21. (set #source "SYS:") ; Default source
  22. (set #backupname "bck_PCPrefs") ; Name of the backed up file
  23.  
  24. ;-----------------------------------------------------------------------------
  25. ; Strings
  26. ;-----------------------------------------------------------------------------
  27. (set #string1 "PCPrefs patching\n\nYou are about to execute a script, which will install Finnish translation patch to the Bridgeboard's 'PCPrefs' program. Original program will be backed up as a 'bck_PCPrefs'.")
  28. (set #string2 "Please, select original PCPrefs file.")
  29. (set #string20 "")
  30. (set #string3 "Backing up PCPrefs... ")
  31. (set #string30 "")
  32. (set #string4 "Creating patched file... ")
  33. (set #string40 "")
  34. (set #string5 "Patching successfully completed!")
  35. (set #string6 "Installation aborted. PCPrefs version 36.49 required.")
  36.  
  37. ;-----------------------------------------------------------------------------
  38. ; SUBROUTINES SUBROUTINES SUBROUTINES SUBROUTINES SUBROUTINES SUBROUTINES SUB
  39. ;-----------------------------------------------------------------------------
  40. ;-----------------------------------------------------------------------------
  41. ; TITLE        : p_DecodeVersion
  42. ; VERSION      : 0.10
  43. ; DATE         : 30.08.1998
  44. ; DESCRIPTION  : Get version and revision from raw version number
  45. ; INPUT        : #version - raw version number
  46. ; OUTPUT       : #ver     - version number
  47. ;                #rev     - revision number
  48. ;-----------------------------------------------------------------------------
  49. ; MODIFICATIONS: -
  50. ;-----------------------------------------------------------------------------
  51. (procedure p_DecodeVersion #version
  52.    (set #ver (/ #version 65536))
  53.    (set #rev (- #version (* #ver 65536)))
  54. )
  55.  
  56. ;-----------------------------------------------------------------------------
  57. ; TITLE        : p_EncodeVersion
  58. ; VERSION      : 0.10
  59. ; DATE         : 30.08.1998
  60. ; DESCRIPTION  : Create raw version number from version and revision number
  61. ; INPUT        : #ver     - version number
  62. ;                #rev     - revision number
  63. ; OUTPUT       : #version - raw version number
  64. ;-----------------------------------------------------------------------------
  65. ; MODIFICATIONS: -
  66. ;-----------------------------------------------------------------------------
  67. (procedure p_EncodeVersion #ver #rev
  68.    (set #version (+ (* #ver 65536) #rev))
  69. )
  70.  
  71. ;-----------------------------------------------------------------------------
  72. ; MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN MAIN
  73. ;-----------------------------------------------------------------------------
  74. ; Set some paths
  75. (set @execute-dir "/Suomi")
  76. (set @default-dest '""')
  77.  
  78. ; Show some info
  79. (message
  80.     (#string1)
  81.     (all)
  82. ); message
  83.  
  84. ; 0% done
  85. (complete 0)
  86.  
  87. ; Ask PCPrefs file
  88. (set #srcfile
  89.     (askfile
  90.         (prompt #string2)
  91.         (help #string20)
  92.         (default #source)
  93.     ); askfile
  94. ); set
  95.  
  96. ; Check PCPrefs version
  97. (set #srcversion
  98.     (getversion #srcfile)
  99. ); set
  100.  
  101. (p_EncodeVersion #pcprefs_ver #pcprefs_rev)
  102.  
  103. (if (= #srcversion #version)
  104.     ; We have required version
  105.     (
  106.         ; Copy old file to a new name
  107.         (set #trgpath (pathonly #srcfile))
  108.         (copyfiles
  109.             (prompt #string3)
  110.             (help #string30)
  111.             (source #srcfile)
  112.             (dest #trgpath)
  113.             (newname #backupname)
  114.         ); copyfiles
  115.  
  116.         ; 50% done
  117.         (complete 50)
  118.  
  119.         ; Create patched file
  120.         (set #command 'WriteStrings %s TO %s DESCRIPTION="%s" QUIET')
  121.         (run
  122.             (#command (tackon #trgpath #backupname) #srcfile "Strings/Translated/PCPrefs.dsc")
  123.             (prompt #string4)
  124.             (help #string40)
  125.         ); run
  126.  
  127.         ; 100% done
  128.         (complete 100)
  129.  
  130.         ; Show exit message
  131.         (exit #string5 (quiet))
  132.     ); true
  133.     ; Wrong version: can't patch
  134.     (
  135.         (exit #string6 (quiet))
  136.     ); false
  137. ); if
  138.